2014年6月16日月曜日

ThinApp のキャプチャ環境の設定変更を一括で行うコマンド

アプリ仮想化奉行 さんHorizon View Client 2.2 仮想化 レシピ 内の、
特記事項に書いてある設定について、

  • Windows Update  無効化(サービスの設定で停止&無効)
  • Windows Defender 無効化(サービスの設定で停止&無効)
  • Windows Search  無効化(サービスの設定で停止&無効)
  • スクリーンセーバー 無効化
  • ネットワーク 無効化 (仮想マシンのNICを切断)
  • 省電力モード 無効化

すべてコマンドで用意してみます。これによって、設定のし忘れを防ぐ目的です。(自分自身も含め…)

  • Windows Update  無効化(サービスの設定で停止&無効)
sc config wuauserv start= disabled
sc stop wuauserv
  • Windows Defender 無効化(サービスの設定で停止&無効)
sc config WinDefend start= disabled
sc stop WinDefend
  • Windows Search  無効化(サービスの設定で停止&無効)
sc config WSearch start= disabled
sc stop WSearch 
  • スクリーンセーバー 無効化
reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v ScreenSaveActive /t REG_SZ /d 0
  • ネットワーク 無効化 (仮想マシンのNICを切断)
netsh interface set interface "ローカル エリア接続" disabled
  • 省電力モード 無効化
powercfg.exe -SETACTIVE (GUID)
ただし、省電力モードの powercfg に関しては、GUID を引数に与える必要があるため、「高パフォーマンス」のGUIDを拾うように、バッチファイル内で処理します。

すべて選択して、拡張子を .cmd か、.bat に変更して保存してください。(ダブルクリックで選択できます)
@ECHO OFF
SETLOCAL

REM Windows Update
sc config wuauserv start= disabled
sc stop wuauserv

REM Windows Defender
sc config WinDefend start= disabled
sc stop WinDefend

REM Windows Search
sc config WSearch start= disabled
sc stop WSearch

REM スクリーンセーバー
reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v ScreenSaveActive /t REG_SZ /d 0 /f

REM ネットワーク接続
netsh interface set interface "ローカル エリア接続" disabled

REM 省電力モード
FOR /F "tokens=3" %%i in ('powercfg -list ^| findstr 高パフォーマンス') DO SET GUID=%%i
powercfg.exe -SETACTIVE %GUID%

ECHO 設定が完了しました
ping -n 5 localhost >NUL